------------------------------------------------------------------------------
------------------------------------------------------------------------------
-- This file is part of 'Finite Field Arithmetic', aka 'FFA'.               --
--                                                                          --
-- (C) 2019 Stanislav Datskovskiy ( www.loper-os.org )                      --
-- http://wot.deedbot.org/17215D118B7239507FAFED98B98228A001ABFFC7.html     --
--                                                                          --
-- You do not have, nor can you ever acquire the right to use, copy or      --
-- distribute this software ; Should you use this software for any purpose, --
-- or copy and distribute it to anyone or in any manner, you are breaking   --
-- the laws of whatever soi-disant jurisdiction, and you promise to         --
-- continue doing so for the indefinite future. In any case, please         --
-- always : read and understand any software ; verify any PGP signatures    --
-- that you use - for any purpose.                                          --
--                                                                          --
-- See also http://trilema.com/2015/a-new-software-licensing-paradigm .     --
------------------------------------------------------------------------------
------------------------------------------------------------------------------

with Word_Ops; use Word_Ops;


-- Fundamental Arithmetic operators on FZ:
package body FZ_Arith is
   
   -- Destructive Add: X := X + Y; Overflow := Carry; optional OF_In
   procedure FZ_Add_D(X          : in out FZ;
                      Y          : in     FZ;
                      Overflow   : out    WBool;
                      OF_In      : in     WBool := 0) is
      Carry : WBool := OF_In;
   begin
      for i in 0 .. Word_Index(X'Length - 1) loop
         declare
            A : constant Word := X(X'First + i);
            B : constant Word := Y(Y'First + i);
            S : constant Word := A + B + Carry;
         begin
            X(X'First + i) := S;
            Carry          := W_Carry(A, B, S);
         end;
      end loop;
      Overflow := Carry;
   end FZ_Add_D;
   
   
   -- Destructive Add: X := X + W; Overflow := Carry
   procedure FZ_Add_D_W(X        : in out FZ;
                        W        : in     Word;
                        Overflow : out    WBool) is
      Carry : Word := W;
   begin
      for i in X'Range loop
         declare
            A : constant Word := X(I);
            S : constant Word := A + Carry;
         begin
            X(i)  := S;
            Carry := W_Carry(A, 0, S);
         end;
      end loop;
      Overflow := Carry;
   end FZ_Add_D_W;

   
   -- Sum := X + Y; Overflow := Carry
   procedure FZ_Add(X          : in  FZ;
                    Y          : in  FZ;
                    Sum        : out FZ;
                    Overflow   : out WBool) is
      Carry : WBool := 0;
   begin
      for i in 0 .. Word_Index(X'Length - 1) loop
         declare
            A : constant Word := X(X'First + i);
            B : constant Word := Y(Y'First + i);
            S : constant Word := A + B + Carry;
         begin
            Sum(Sum'First + i) := S;
            Carry  := W_Carry(A, B, S);
         end;
      end loop;
      Overflow := Carry;
   end FZ_Add;
   
   
   -- Gate = 1: Sum := X + Y; Overflow := Carry
   -- Gate = 0: Sum := X;     Overflow := 0
   procedure FZ_Add_Gated_O(X          : in  FZ;
                            Y          : in  FZ;
                            Gate       : in  WBool;
                            Sum        : out FZ;
                            Overflow   : out WBool) is
      Carry : WBool := 0;
      Mask  : constant Word := 0 - Gate;
   begin
      for i in 0 .. Word_Index(X'Length - 1) loop
         declare
            A : constant Word := X(X'First + i);
            B : constant Word := Y(Y'First + i) and Mask;
            S : constant Word := A + B + Carry;
         begin
            Sum(Sum'First + i) := S;
            Carry  := W_Carry(A, B, S);
         end;
      end loop;
      Overflow := Carry;
   end FZ_Add_Gated_O;
   
   
   -- Same as FZ_Add_Gated_O, but without Overflow output
   procedure FZ_Add_Gated(X          : in  FZ;
                          Y          : in  FZ;
                          Gate       : in  WBool;
                          Sum        : out FZ) is
      Overflow : Word;
      pragma Unreferenced(Overflow);
   begin
      FZ_Add_Gated_O(X, Y, Gate, Sum, Overflow);
   end FZ_Add_Gated;
   
   
   -- Destructive Sub: X := X - Y; Underflow := Borrow
   procedure FZ_Sub_D(X          : in out FZ;
                      Y          : in     FZ;
                      Underflow  : out    WBool) is
      Borrow : WBool := 0;
   begin
      for i in 0 .. Word_Index(X'Length - 1) loop
         declare
            A : constant Word := X(X'First + i);
            B : constant Word := Y(Y'First + i);
            S : constant Word := A - B - Borrow;
         begin
            X(X'First + i) := S;
            Borrow         := W_Borrow(A, B, S);
         end;
      end loop;
      Underflow := Borrow;
   end FZ_Sub_D;
   
   
   -- Difference := X - Y; Underflow := Borrow
   procedure FZ_Sub(X          : in  FZ;
                    Y          : in  FZ;
                    Difference : out FZ;
                    Underflow  : out WBool) is
      Borrow : WBool := 0;
   begin
      for i in 0 .. Word_Index(X'Length - 1) loop
         declare
            A : constant Word := X(X'First + i);
            B : constant Word := Y(Y'First + i);
            S : constant Word := A - B - Borrow;
         begin
            Difference(Difference'First + i) := S;
            Borrow := W_Borrow(A, B, S);
         end;
      end loop;
      Underflow := Borrow;
   end FZ_Sub;
   
   
   -- Difference := X - W; Underflow := Borrow
   procedure FZ_Sub_W(X          : in  FZ;
                      W          : in  Word;
                      Difference : out FZ;
                      Underflow  : out WBool) is
      Borrow : Word := W;
   begin
      for i in 0 .. Word_Index(X'Length - 1) loop
         declare
            A : constant Word := X(X'First + i);
            S : constant Word := A - Borrow;
         begin
            Difference(Difference'First + i) := S;
            Borrow := W_Borrow(A, 0, S);
         end;
      end loop;
      Underflow := Borrow;
   end FZ_Sub_W;
   
   
   -- Destructive: If Cond is 1, NotN := ~N; otherwise NotN := N.
   procedure FZ_Not_Cond_D(N    : in out FZ;
                           Cond : in     WBool)is
      
      -- The inversion mask
      Inv : constant Word := 0 - Cond;
      
   begin
      
      for i in N'Range loop
         
         -- Invert (or, if Cond is 0, do nothing)
         N(i) := N(i) xor Inv;
         
      end loop;
      
   end FZ_Not_Cond_D;
   
   
   -- Subtractor that gets absolute value if underflowed, in const. time
   procedure FZ_Sub_Abs(X          : in FZ;
                        Y          : in FZ;
                        Difference : out FZ;
                        Underflow  : out WBool) is
      
      O : Word := 0;
      pragma Unreferenced(O);
      
   begin
      
      -- First, we subtract normally
      FZ_Sub(X, Y, Difference, Underflow);
      
      -- If borrow - negate,
      FZ_Not_Cond_D(Difference, Underflow);
      
      -- ... and also increment.
      FZ_Add_D_W(Difference, Underflow, O);
      
   end FZ_Sub_Abs;
   
   
end FZ_Arith;